Initial commit

uni_modules/uts-openSchema/utssdk/app-android/config.json

@@ -0,0 +1,3 @@
+{
+  "minSdkVersion": "21"
+}

uni_modules/uts-openSchema/utssdk/app-android/index.uts

@@ -0,0 +1,27 @@
+import Intent from 'android.content.Intent'
+import Uri from 'android.net.Uri'
+import { OpenSchema, CanOpenURL } from '../interface.uts'
+
+export const openSchema : OpenSchema = function (url : string) {
+  if (canOpenURL(url)) {
+    const context = UTSAndroid.getUniActivity()!
+    const uri = Uri.parse(url)
+    const intent = new Intent(Intent.ACTION_VIEW, uri)
+    intent.setFlags(Intent.FLAG_ACTIVITY_NEW_TASK)
+    intent.setData(uri)
+    context.startActivity(intent)
+  } else {
+    console.error('[uts-openSchema] url param Error：', JSON.stringify(url))
+  }
+}
+
+export const canOpenURL : CanOpenURL = function (url : string) : boolean {
+  if (typeof url === 'string' && url.length > 0) {
+    const context = UTSAndroid.getUniActivity()!
+    const uri = Uri.parse(url)
+    const intent = new Intent(Intent.ACTION_VIEW, uri)
+    return intent.resolveActivity(context.packageManager) != null ? true : false
+  } else {
+    return false
+  }
+}

uni_modules/uts-openSchema/utssdk/app-harmony/index.uts

@@ -0,0 +1,19 @@
+import { bundleManager, common } from '@kit.AbilityKit'
+import OpenLinkOptions from '@ohos.app.ability.OpenLinkOptions'
+import { getAbilityContext } from '@dcloudio/uni-runtime'
+import { OpenSchema, CanOpenURL } from '../interface.uts'
+
+export const openSchema : OpenSchema = function (url : string) : void {
+  ;(getAbilityContext() as common.UIAbilityContext)?.openLink(url, {
+    appLinkingOnly: false
+  } as OpenLinkOptions)
+}
+
+export const canOpenURL : CanOpenURL = function (url : string) : boolean {
+  try {
+    return bundleManager.canOpenLink(url)
+  } catch (error) {
+    console.error('[uts-openSchema] url param Error：', JSON.stringify(url))
+    return false
+  }
+}

uni_modules/uts-openSchema/utssdk/app-ios/config.json

@@ -0,0 +1,3 @@
+{
+  "deploymentTarget": "12.0"
+}

uni_modules/uts-openSchema/utssdk/app-ios/index.uts

@@ -0,0 +1,22 @@
+import { UIApplication } from 'UIKit'
+import { URL } from 'Foundation'
+import { OpenSchema, CanOpenURL } from '../interface.uts'
+
+export const openSchema : OpenSchema = function (url : string) : void {
+  if (canOpenURL(url)) {
+    let uri = new URL(string = url)
+    UIApplication.shared.open(uri!)
+  } else {
+    console.error('[uts-openSchema] url param Error: ', url)
+  }
+}
+
+export const canOpenURL : CanOpenURL = function (url : string) : boolean {
+  if (typeof url == 'string' && url.length > 0) {
+    let uri = new URL(string = url)
+    if (uri != null && UIApplication.shared.canOpenURL(uri!)) {
+      return true
+    }
+  }
+  return false
+}

uni_modules/uts-openSchema/utssdk/interface.uts

@@ -0,0 +1,2 @@
+export type OpenSchema = (url : string) => void
+export type CanOpenURL = (url : string) => boolean

uni_modules/uts-openSchema/utssdk/web/index.uts

@@ -0,0 +1,12 @@
+import { OpenSchema, CanOpenURL } from '../interface.uts'
+
+export const openSchema : OpenSchema = function (url : string) : void {
+  location.href = url
+}
+
+export const canOpenURL : CanOpenURL = function (url : string) : boolean {
+  if (url != '') {
+    return true
+  }
+  return false
+}